/*
  Lightning Talk Timer
 
 Show green light during bulk of talk.  Show yellow in the last
 10 seconds.  Show red when the time is up.
 
 The circuit:
 * Green LED connected from digital pin 9 to ground.
 * Red LEDs connected from digital pins 12,13 to ground.
 * Yellow LEDs connected from digital pins 10,11 to ground.
 * Note: On most Arduino boards, there is already an LED on the board
 connected to pin 13, so you don't need any extra components for this example.
 
 Created 29 July 2010
 By Ralph Green
 
 based on an orginal by H. Barragan for the Wiring i/o board
 
 */
int switchPin = 2;              // Switch connected to digital pin 2
int redLedPin1 = 12;    // LED connected to digital pin 12
int redLedPin2 = 13;    // LED connected to digital pin 13
int yellowLedPin1 = 10;    // LED connected to digital pin 10
int yellowLedPin2 = 11;    // LED connected to digital pin 11
int greenLedPin =  9;    // LED connected to digital pin 9
int which, CounterState;
int pause;
int killLoopCounter;
unsigned long startTime, newTime, nextStepTime;
unsigned long TalkLengthSeconds = 300;
unsigned long WarningTimeSeconds = 10;

// The setup() method runs once, when the sketch starts

void setup()   {                
  Serial.begin(9600);           // set up Serial library at 9600 bps
  pinMode(switchPin, INPUT);    // sets the digital pin as input to read switch
  // initialize the digital pin as an output:
  pinMode(greenLedPin, OUTPUT);     
  pinMode(redLedPin1, OUTPUT);     
  pinMode(redLedPin2, OUTPUT);     
  pinMode(yellowLedPin1, OUTPUT);     
  pinMode(yellowLedPin2, OUTPUT);     
  digitalWrite(greenLedPin, LOW);   // set the LED off
  digitalWrite(redLedPin1, LOW);    // set the LED off
  digitalWrite(redLedPin2, LOW);    // set the LED off
  digitalWrite(yellowLedPin1, LOW);    // set the LED off
  digitalWrite(yellowLedPin2, LOW);    // set the LED off
  digitalWrite(greenLedPin, HIGH);   // set the LED on
  delay(400);                  // wait for a bit
  digitalWrite(greenLedPin, LOW);   // set the LED of
  digitalWrite(yellowLedPin1, HIGH);    // set the LED on
  digitalWrite(yellowLedPin2, HIGH);    // set the LED on
  delay(400);                  // wait for a bit
  digitalWrite(yellowLedPin1, LOW);    // set the LED off
  digitalWrite(yellowLedPin2, LOW);    // set the LED off
  digitalWrite(redLedPin1, HIGH);    // set the LED on
  digitalWrite(redLedPin2, HIGH);    // set the LED on
  delay(400);                  // wait for a bit
  digitalWrite(redLedPin1, LOW);    // set the LED off
  digitalWrite(redLedPin2, LOW);    // set the LED off
  delay(400);                  // wait for a bit
  which = 1;
  CounterState = 0;
  killLoopCounter = 0;
}

// the loop() method runs over and over again,
// as long as the Arduino has power

void loop()                     
{
//  Serial.println(CounterState);
  switch (CounterState) {
  case 0: // Initial state. Blink to tell the world you are alive
    if (digitalRead(switchPin) == 1) {// Read the pin
      CounterState = 1;
      startTime = millis();
      nextStepTime = (TalkLengthSeconds - WarningTimeSeconds) * 1000;
      pause = 0;
    }
    else {
      if (--killLoopCounter < 1) {
        killLoopCounter = 80;
        digitalWrite(greenLedPin, HIGH);   // set the LED on
      }
      else if (killLoopCounter < 78) {
        digitalWrite(greenLedPin, LOW);   // set the LED on
      }
      delay(40);                  // wait for a bit
    }
    break;
  case 1: // Start countdown for the main part of the talk
    newTime = millis();
    if (digitalRead(switchPin) == 1) {// Read the pin
      if (pause == 0) {
        pause = 1;
        nextStepTime -= (newTime - startTime);
      }
      digitalWrite(greenLedPin, LOW);   // set the LED off
      break;
    }
    else {
      if (pause == 1) { // we must be coming off a pause
        pause = 0;
        newTime = startTime = millis();
      }
      digitalWrite(greenLedPin, HIGH);   // set the LED on
      delay(20);                  // wait for 20 milliseconds
    }
    if ((newTime - startTime) > nextStepTime) {
      CounterState = 2;
      startTime = millis();
      nextStepTime = WarningTimeSeconds * 1000;
    }
    break;
  case 2: // Warn that the time for the talk is almost over
    newTime = millis();
    digitalWrite(greenLedPin, LOW);   // set the LED off
    digitalWrite(yellowLedPin1, HIGH);   // set the LED on
    digitalWrite(yellowLedPin2, HIGH);   // set the LED on
    if ((newTime - startTime) > nextStepTime) {
      CounterState = 3;
    }
    break;
  case 3: // Show that time is up until button signals another round
    digitalWrite(yellowLedPin1, LOW);   // set the LED off
    digitalWrite(yellowLedPin2, LOW);   // set the LED off
    digitalWrite(redLedPin1, HIGH);    // set the LED on
    digitalWrite(redLedPin2, HIGH);    // set the LED on
    if (digitalRead(switchPin) == 1) // Read the pin and display the value
      CounterState = 4;
    else
      delay(20);                  // wait for a bit
    break;
  default: // Reset variables for another lightning talk round
    digitalWrite(greenLedPin, LOW);   // set the LED off
    digitalWrite(redLedPin1, LOW);    // set the LED off
    digitalWrite(redLedPin2, LOW);    // set the LED off
    digitalWrite(yellowLedPin1, LOW);    // set the LED off
    digitalWrite(yellowLedPin2, LOW);    // set the LED off
    which = 1;
    CounterState = 0;
    killLoopCounter = 0;
    delay(250);                  // wait for a quarter second
  }
}